informa
/
Featured Blog

The Statue Got Me High: Annotated Source

Here's the Inform 7 source text to my 2012 game "The Statue Got Me High," based on the They Might Be Giants song of the same name. In 2015 and 2017 I added annotations commenting on the design, the implementation, and various TMBG references.

I've annotated source text for several of my text adventures, to distribute to a certain tier of my Patreon supporters. One such Patreoneer told me that I should make some of the older annotations available publicly. Now, I'm not one to allow my Patreon supporters to boss me around—I'm an artist, and very passionate about my artistic integrity—but in this case the guy making the suggestion was Simon Carless, and him I do allow to boss me around.

So here is the annotated source code text of Simon's favorite game, "The Statue Got Me High." If you haven't played this game, you should definitely give it a look before you wade into the source. It shouldn't take more than an hour to play through.

"The Statue Got Me High," written as part of a tribute to the They Might Be Giants album Apollo 18 in 2012, is I think the third game I ever released. The nuts and bolts of the implementation do not meet the high standards that I hold myself to as an Inform 7 developer in 2017. Some of the code is embarrassing. But if you're interested in using Inform 7 to create text adventures, this should be a useful example to you—just, please, promise me you won't learn too much.

"The Statue Got Me High"

by Ryan Veeder (with apologies to Johns L & F)

Volume 0 - Introduction to the Annotated Source Code Text

[% Comments in brackets and italics, beginning with a % for some reason, are my 2015 annotations—or my 2017 annotations, new to this general release of the source text. Comments in brackets but not in italics are my original comments to the code, but you won't see many of those. The division headings are all original to the source, except for the one above, obviously. Oddly, it looks like I never declared a "Volume 1." Well, it's too late to do anything about it now.

The most basic explanation of this game's existence is explicated under "carry out abouting" below. I felt really lucky that I got "dibs" on my favorite Apollo 18 track (one of my favorite TMBG tracks, maybe one of my all-time favorite songs) and I really wanted to do it justice. I remember discussing the concept with my brother: That I should pay simultaneous homage to the Commendatore scene in Don Giovanni was a given, but I think it was his idea for the player character to fill the Leporello role. (Sean and I are big fans of the Commendatore scene only because our dad played that part of Amadeus for us over and over again when we were kids. We are not opera buffs.)

I also remember Sean worrying that if I released a game were centered around a dinner, following on the heels of Taco Fiction and You've got a Stew Going, I ran the risk of becoming "the food guy," the Weird Al of IF. I knew the risks, and I made this game. History will be my judge.]

The release number is 2.

[% I am sorry to say I have very little idea of what was changed or fixed for this version. I remember the wine bottles were very buggy, and so was John's behavior in the final scene. There are still bugs in this version, but rather than fix them for a version 3, I'll try to point them out to you as we go.]

The story headline is "A disaster simulator".

The story description is "As his personal assistant, your duty tonight is to make sure John's party is successful. This will not happen. Written for the Apollo 18+20 tribute album project."

[% This story description is uncharacteristically wordy, and on IFDB I've pared it down quite a bit. My philosophy on "blurbs" is informed quite a bit by how much Emily Short disliked the original blurb for Taco Fiction and how much Jenni Polodna loved the sentence "Taco Fiction is a game about crime."]

Use no scoring.

[% The latest versions of Inform 7 assume that a game will not use scoring—also, the latest versions of Inform 7 use the term "story" rather than "game." Back in 2012, though, you had to explicitly turn this option off.]

Include Basic Screen Effects by Emily Short.

[% Emily Short's Basic Screen Effects extension is what I use to make the player Press Any Key To Continue, a technique I rely on to manage pacing at a couple different points in this game.]

Release along with cover art and an interpreter.

Abouting is an action out of world. Understand "help" and "about" and "walkthrough" and "hint" as abouting.

Carry out abouting: say "[italic type]This game was written for the Apollo 18+20 project, organized by Professor Doctor Doctor Kevin Jackson-Mead, DDS. It's based on a song by They Might Be Giants.[paragraph break]My brother Sean and my friend Zach helped me out a lot with the concept and stuff, so props to those guys. This version fixes many bugs that were found by ClubFloyd, so props to those guys as well.[paragraph break]If you find yourself stuck in the game, just make sure you talk to everyone and explore everything thoroughly. Things [if the statue is onice]aren't as bad[otherwise]are exactly as bad[end if] as they seem[roman type]."

[% The "onice" or "onfire" status of the statue object is used as a global variable, indicating that things either have taken a sharp left turn or they haven't yet. When things get crazy, basically every bit of text in the game has to change to reflect that, so we'll see an "if... otherwise... end if" structure used over and over again.]

When play begins:
  now the right hand status line is "";
  say "John was already on his phone by the time you glanced over your shoulder. He had forgotten the whole joke; he wouldn't have noticed if you just turned around and walked back. Which you really wanted to do, for some reason.

It felt like a pretty stupid thing to be afraid of.

You got up the nerve to walk past the last few headstones, but you kept your head down. You didn't even want to look at the feet. You just kept your eyes on the pedestal, on the exact spot where you finally set down the envelope, and then you turned around.

John was still talking to his phone, oblivious. You could feel it, though, like a finger lightly scraping up the back of your neck.

And then jabbing into your spine so you had to turn back around and look up at its face. And you thought (right away you told yourself the idea was ridiculous) that it nodded.

[fixed letter spacing] [variable letter spacing][italic type][bracket]press any key[close bracket][roman type][paragraph break]";
  wait for any key;

[% I find myself unsatisfied with this introductory text. The problem is that the premise is too convoluted to support such an air of mystery. "Inviting a statue of a dead guy to a party" is a complicated concept, and has to be expressed somewhat explicitly in order for what follows to be intelligible.]

Chapter - Boring

[% Nowadays I typically make "Boring" its own volume. These are mostly verbs that don't affect the game state, but which, if I didn't assign new responses, wouldn't match the tone of the rest of the prose.]

The description of the player is "[if the statue is onfire]Suddenly you find the thought of looking at yourself disgusting.[otherwise]You look extremely presentable in your 'B' tuxedo: classy, but not too flashy; easy to ignore. Tuxedo B is the most appropriate for these intimate get-togethers with John's close friends. ([quotation mark]Intimate' is the word John uses for mixed groups; the parties to which only women are invited he calls 'friendly,' and they require a different tuxedo.)[end if]"

Instead of taking some scenery: Say "[if the location is Kitchen or the location is Tunnel or the location is Wine Cellar]You won't be needing that. You assume as much, anyway[otherwise if the statue is onfire]You can't save it. You have to escape[otherwise]It would be untoward to try rearranging [the noun] while guests are over[end if]."

Instead of attacking something: say "[if the statue is onfire]Violence begets violence begets violence et cetera et cetera et cetera[otherwise]No matter how frustrating things become, you must try to keep your head[end if]."

Instead of attacking someone: say "[if the statue is onfire]Violence begets violence begets violence et cetera et cetera et cetera[otherwise]No matter how frustrating things become, you must try to keep your head[end if]."

Instead of kissing someone: say "[if the statue is onfire]Too late for that[otherwise]Keep your mind on the party[end if]."

Check eating:
  if the noun is edible:
    say "That's for the guests." instead;
  otherwise:
    say "Surely you are not so desperate." instead.

[% I just checked, and NOTHING IN THE GAME IS EDIBLE. So much for being the Weird Al of IF!]

Instead of waking up: say "[if the statue is onfire]What makes you think this isn't real?[otherwise]You are very much awake.[end if]"

Instead of sleeping, say "[if the statue is onfire]You can sleep when you're dead[unicode 8212]which might be right now, actually. Hmm[otherwise]You'll have plenty of time to sleep after the party[end if]."

Instead of entering something:
  say "You are not the type to sit down on the job."

[% This makes more sense than it seems to, because Inform 7's default world model has a single "entering" action that covers going through doors, climbing inside of containers, and sitting down on things. When I added this rule I probably hadn't thought very much about exactly what enterable containers or sit-on-able supporters would be in the game, but I knew enough about the player character to decide that I should probably block this action generally—There's always the option to override a general rule like this with more specific rules.

UNFORTUNATELY I didn't think about this quite hard enough, so "You are not the type to sit down on the job" is also the response to >ENTER DOOR. Whoops!!!]

Chapter 2 - Rooms

Section 1 - Kitchen

Kitchen is a room. "[if the statue is onfire]Where's Chucky? It looks like he left in a hurry.[paragraph break]There seems to be something happening down in the dining room[otherwise]The kitchen, with all its drawers, its cupboards, its sinks and ovens, constitutes Chucky's domain, and he guards it jealously. Usually you use it only as a conduit between the dining room (south) and the tunnel to the cellar (down the stairs).[paragraph break]Of course, working in here is part of your job, so you and Chucky have a deal worked out. The deal is: You do not touch [italic type]anything[roman type][end if]."

The stairs are a backdrop. Understand "stair" as the stairs. The stairs are in Kitchen and Tunnel. The description of the stairs is "Creaky, but not dangerous."

Understand "go down stairs" and "go downstairs" as descending.

Descending is an action applying to nothing. Carry out descending: try going down.

Understand "go upstairs" and "go up stairs" as ascending. Ascending is an action applying to nothing. Carry out ascending: try going up.

Instead of taking the stairs:
  if the location is kitchen:
    try going down instead;
  otherwise if the location is tunnel:
    try going up instead.

The kitchen paraphenalia is scenery in the kitchen. Understand "cooking" or "sink" or "sinks" or "drawer" or "drawers" or "cupboard" or "cupboards" or "oven" or "ovens" or "knife" or "spoon" or "fork" or "counter" as the kitchen paraphenalia. The description of the kitchen paraphenalia is "[if the statue is onfire]No, Chucky might be back any minute[otherwise]If you just stand around looking, Chucky will start getting surly[end if]." Instead of doing something other than examining with the kitchen paraphenalia, say "You better not. Chucky would go ballistic."

Chucky is a man in Kitchen. Understand "cook" as Chucky. The initial appearance of Chucky is "[if Chucky carries the stack of place cards]Right now is an exception, apparently.[paragraph break]'John wants you to take care of these,' he squawks, thrusting a stack of cards toward you[otherwise]Chucky [one of]busies himself with some arcane cooking implements[or]just stares, with his one glass eye[or]looks like he wants to hit you[or]takes a quick pull from a bottle of vanilla extract[as decreasingly likely outcomes][end if]."

[% Chucky is an homage to the song "Cyclops Rock," whence his name, his one glass eye, his tombstone smile, and his antisocial tendencies. I believe the president he served under must be Nixon.]

The description of Chucky is "Chucky's teeth look like a cemetery built on some old marshland, his glass eye is not the same color as his real eye, and he smells like a butchery, but he is a phenomenal cook. Supposedly he used to be a chef in the White House.[paragraph break]You'd like to find out more about that, but Chucky isn't the kind of guy who likes to talk. To you."

The tombstone smile is part of Chucky. Understand "teeth" or "tooth" as the tombstone smile. The description of the tombstone smile is "You would think if he really worked for the President, he would be able to afford an orthodontist."

The glass eye is part of Chucky. The description of the glass eye is "His real eye is blue-white, but the glass one is dark green. You don't really like looking straight at it, but you guess doing that would be kind of rude anyway.[paragraph break]Chucky has said, for the record, that he lost the original 'in a fight.' When you told this to John, he said 'Yeah, a fight with a fishing pole!' But he might have been joking."

Instead of asking Chucky about something, say "Chucky isn't big on conversation, even with his friends (you assume)."

Instead of telling Chucky about something, say "Chucky isn't big on conversation, even with his friends (you assume)."

Understand "talk to [Chucky]" as a mistake ("Chucky isn't big on conversation, even with his friends (you assume).").

Chucky carries a stack of place cards. Understand "card" or "stack of cards" or "name cards" as the stack of place cards. The description of the stack of place cards is "The papers are place cards, which are to be set out at the dinner table so everyone knows where to sit. The forms of the names are inconsistent: The men are 'John,' 'Miles,' 'Ivan,' and 'Garry,' but the women are 'Miss Idie' and 'Miss O.'[paragraph break]But that's not your problem. Your job is figuring out where to put these."

[% Forcing the player to get the place cards requires a bit of work. Looking back I wonder why I didn't say "Chucky shoves the cards into your hands" and start the game with the cards in your inventory. I guess I thought it was important to let the player screw around for the first turn instead.]

Check examining the stack of place cards:
  If Chucky carries the stack of place cards:
    say "As you lean in for a closer look, Chucky draws back, repulsed by your intrusion of his personal space.[paragraph break]'Just take [']em, will ya?' he growls. He shoves the stack into your hands and then turns to his cooking.";
    now the player carries the stack of place cards;
    continue the action;

Check taking the stack of place cards:
  if chucky is carrying the stack of place cards:
    now the player is carrying the stack of place cards;
    say "Once the cards are in your hands, Chucky spins around and returns to his cooking." instead.

Check going in Kitchen:
  if Chucky carries the stack of place cards:
    say "'Where do you think you're goin[']?' Chucky barks. 'These cards ain't my job.'" instead.

Instead of going nowhere in Kitchen, say "The stairs go down to the cellar, and south from here is the dining room, and those are the only directions available to you."

Section 2 - Dining Room

Dining is a room. "[if the statue is onfire]Everything is on fire. The floor is burning and the walls are burning and the table looks like a big bonfire; all the settings are twinkling in the light of the flames. The room is rapidly filling with smoke[otherwise]The sun is going down outside the western window, and the huge table, set for six, is aflame in the orange glow. An old portrait hangs on one wall, watching the proceedings with creepy indifference.[paragraph break]The kitchen is back north, the den is east from here, and a narrow door leads south to the foyer[end if]."

The printed name of Dining is "Dining Room". Dining is south of Kitchen.

The huge table is a scenery supporter in dining. The description of the huge table is "[if the statue is onfire]The table has been flipped over and set aflame. The high-backed chairs have been thrown on top like logs. The conflagration is too bright to look at directly[otherwise]At other parties this table has comfortably seated more, but currently there are six high-backed chairs and six table settings: Two each on the north and south sides, one on the west end, and one at the east. This last one, on account of its facing the west wall, has the sunset shining straight at it[end if]."

Some high-backed chairs are scenery in dining. Understand "chair" as the high-backed chairs. The description of the high-backed chairs is "[if the statue is onfire]There are only four chairs burning here. Where are the other two? You doubt they were rescued[otherwise]Depending on the style of dinner to be served, John will request one of the various sets of chairs that he owns to be placed at the table. How he decides which chairs should go with which meals is a mystery[end if]."

Some settings are scenery in dining. The printed name of the settings is "table settings". Understand "table settings" or "setting" or "fork" or "knife" or "spoon" or "salad fork" or "glass" or "plate" or "chopstick" as the settings. The description of the settings is "[if the statue is onfire]Beyond your help, now[otherwise]You look over the settings again, and reposition a [one of]fork[or]spoon[or]salad fork[or]knife[or]glass[or]plate[or]chopstick[at random] ever so slightly.[paragraph break]There. Now it's perfect[end if]."

The portrait is scenery in dining. Understand "John" or "ancestor" or "Don Giovanni" or "Don Juan" or "painting" or "frame" as the portrait. The description of the portrait is "[if the statue is onfire]The man in the portrait reaches out to you for help, but there is nothing you can do[otherwise]The frame on the north wall is too big to ignore, and the eyes of the portrait seem to follow you around.[paragraph break]This is supposed to be John's ancestor, an Old World nobleman, also named John. John has offered numerous anecdotes about the subject of the painting, many of them outlandish and contradictory, and you would be inclined to believe that really has no idea who this man is, if the family resemblence weren't so unnervingly clear[end if]."

[% A sufficiently nerdy player will guess that the ancestor is Don Juan, and we can confirm this hypothesis by understanding "Don Juan" as the portrait. Its creepy eyes also reference TMBG's "No Answer."]

The western window is scenery in dining. Understand "sunset" or "sun" or "setting sun" as the western window. Instead of searching the western window, try examining the noun. The description of the western window is "[if the statue is onfire]Where the window was, there is only a wall of undulating flame[otherwise]The setting sun turns this whole room orange; it's so bright you can't even turn toward it without squinting[unicode 8212]and yet, it is only a middle-sized star[end if]."

[% And here we reference "Why Does The Sun Shine?"!]

Instead of going nowhere in dining, say "[if the statue is onfire]The door to the foyer is blocked. The only way out is east[otherwise]Your available exits are: north to the kitchen, east to the den, and south to the foyer[end if]."

Section 3 - Foyer

Foyer is a room. "[if the statue is onfire]You've almost escaped. The front door is to the south[otherwise]The entrance to the house is somewhat cramped, apparently to allow more room in the parlor to the east. Some steep stairs lead up to the second floor (off-limits, tonight), through a narrow door to the north is the dining room, and the front door leads south and out of the house[end if]."

The narrow door is a door and scenery. The narrow door is north of Foyer and south of Dining. The narrow door is open. The description of the narrow door is "[if open]The narrow door is open, and through it you can see[otherwise]The narrow door is closed, but on the other side of it is[end if] [if the location is foyer]the dining room[otherwise]the foyer[end if]."

Check opening the narrow door:
  if the statue is onfire:
    say "The door is engulfed in flames, impossible to pass." instead.

The front door is a door and scenery. The front door is closed. The front door is north of Lawn and south of Foyer. The description of the front door is "[if the statue is onfire]The door isn't on fire, yet; outside is the lawn, and safety[otherwise]An orange glow burns on the other side of this heavy door[end if]."

Check opening the front door:
  if the statue is onice:
    say "Your duties for the night are inside the house." instead;

After opening the front door:
  say "As you open the door, cool night air rushes in from outside."

The steep stairs is scenery in Foyer. The description of the steep stairs is "[if the statue is onfire]The fire has climbed the stairs and already reached the second floor[otherwise]Vacuuming the carpet on these stairs is one of your favorite jobs, but for some reason you really hate dusting the banister[end if]."

The carpet is part of the steep stairs. The description of the carpet is "[if the statue is onfire]The burning fibers stand at attention, ready to tell you all about how horrible their day has been[otherwise]The freshly-vacuumed fibers stand at attention, ready to receive people's feet[end if]."

Instead of touching the carpet, say "[if the statue is onfire]Your hand passes through the flames like a cannonball through a waterfall, like a meteor through the mesosphere[otherwise]So deep, so soft. You caress the carpet for a bit, and then you rub away the impression left by your hand[end if]."

[% Some neat prose awaits those who bother to take time out to inspect the carpet at the very end of the game!]

The banister is part of the steep stairs. The description of the banister is "[if the statue is onfire]The banister turns away from you in shame[otherwise]You regard the banister with disdain. In just a few days it will be dusty again[end if]."

The broken wall clock is in Foyer. It is fixed in place. The initial appearance of the broken wall clock is "[if the statue is onfire]The wall clock is on the floor, shattered[otherwise]A wall clock hangs silently over you[end if]." The description of the wall clock is "[if the statue is onfire]The exposed gears are sitting around guiltily, waiting for a chance to slink away[otherwise]It's broken; its hands have been stuck at 1:56 for as long as you can remember. John will not permit you to have it fixed[end if]."

[% The clock is stuck at "Four of Two," one of TMBG's kids' songs that started out as a much creepier demo.]

The elephant foot umbrella stand is in Foyer. The umbrella stand is an open unopenable container. The initial appearance of the umbrella stand is "[if the statue is onfire]The elephant foot umbrella stand is here[otherwise]At the bottom of the stairs sits an elephant foot umbrella stand[end if]." The description of the umbrella stand is "[if the statue is onfire]It must have walked here by itself; it's too heavy to be carried[otherwise]John is extremely proud of this extremely illegal conversation piece. He jokes with his lady guests that the rest of the elephant is alive and well: 'He's up in my bedroom,' he says, and then he offers to take her upstairs to see.[paragraph break]This works disturbingly well[end if]."

[% I don't think the umbrella stand is a reference to a TMBG song. I may be misremembering, but I think it was included to reinforce how awful John is.]

Instead of taking the umbrella stand, say "It's too heavy to be lugged around."

Instead of going up in foyer, say "[if the statue is onfire]You'll choke on the smoke even faster if you head up there[otherwise]You don't have to worry about the upstairs for tonight, provided this party doesn't go in an unexpected direction[end if]."

Check going south in foyer:
  if the front door is closed:
    try opening the front door;
    if the front door is open:
      continue the action;

Instead of going nowhere in foyer, say "[if the statue is onfire]The only way out is south[otherwise]Your available exits are north to the dining room, east to the parlor, and south, to the front yard[end if]."

Section 4 - Parlor

Parlor is a room. "[if the statue is onfire]The couch and chair are being rapidly consumed by flames; the rug is almost completely gone.[paragraph break]You can hear people yelling in the foyer to the west[otherwise]This is your favorite room in the house. The décor is classy enough for guests to understand that they should avoid making a mess out of everything.[paragraph break]This is due in large part to the magnificent oriental rug, covering most of the floor, and the delicate sabicu coffee table. Both are in an impossibly pristine condition, capable of inspiring respect from the most boorish of John's associates[end if]." Parlor is east of Foyer.

The beige couch is scenery in Parlor. "[if the statue is onfire]The fire spreads, and ashen black creeps across the suede like a fungus[otherwise]Suede, spotless[end if]."

The easy chair is scenery in Parlor. "[if the statue is onfire]Seams are ripping open in the heat; the edges quickly catch fire[otherwise]You are not allowed to touch John's favorite chair unless you're cleaning it[end if]."

Instead of touching the easy chair, say "You cannot bring yourself to breach your contract[if John is in parlor]. And anyway John is right there[end if]."

The delicate sabicu coffee table is a scenery supporter in Parlor. The description of the coffee table is "[if the statue is onfire]The fire is licking at its base; soon it will be engulfed in flames[otherwise]It's a lovely, lovely piece, regardless of its origins. The vase of lilies you chose is an ideal complement[end if]." The printed name of the coffee table is "coffee table".

Instead of taking the coffee table: say "It's too heavy[if the statue is onfire] for you to save it[end if]."

After examining the coffee table the first time:
  If John is in the location:
    If Miss O is in the location:
      say "Miss O notices that you're looking at the coffee table instead of her. She turns to John.[paragraph break]'I picked this table up during a job in Egypt, remember? Another poor old man with more junk in his life than he knew what to do with. I saw this thing and I could tell in an instant it'd be better off with you. There were complications, though. I wasn't able to take home as much as I wanted.[paragraph break]John's mind has wandered; he takes a moment to respond. 'What kind of complications?'[paragraph break]'Well, the old man was easy; he slept through the whole thing, right? But I was relying on the assistance of his butler. And at the last minute he decided to stop cooperating. So, yeah.'[paragraph break]She glances at you for an instant. Then she closes her eyes and stretches, arching her back. 'I just grabbed his neck for a while until he passed out.'[paragraph break]You look to John. He's trying to look down her dress."

[% It's not explicit in the prose, but Ondine has killed multiple people.]

The vase of lilies is scenery in Parlor. Understand "lily" or "flower" or "flowers" as the vase of lilies. The description of the vase of lilies is "[if the statue is onfire]Garry is holding the lilies over his breast; the vase has disappeared[otherwise]Coral lilies, picking up the orange from the rug, in a eggshell vase to contrast the deep color of the coffee table. John isn't even conscious of how much he relies on you when it comes to stuff like this[end if]."

The magnificent Persian rug is scenery in Parlor. Understand "carpet" or "fibers" as the Persian rug. The description of the rug is "[if the statue is onfire]You can just barely find enough spots that aren't burning yet to get across[otherwise]You've heard again and again the story of how Miss O acquired this carpet (and then so graciously donated it to John). Her speech replays in your mind every time you have to clean it, and it always makes you feel dirty[end if]."

Instead of going nowhere in parlor, say "[if the statue is onfire]The way out is west[otherwise]The foyer is west of here; the den is to the north[end if]."

Section 5 - Den

Den is a room. "[if the statue is onfire]The fire has already spread through here; it's climbing up the sides of the pool table and the credenza[otherwise]This room is well-loved by many of John's friends: from those he's brought home for the first time (because it is cozy and dimly lit) to frequent visitors (because they know there's booze in the credenza). The dining room is west; the parlor is south[end if]." Den is east of Dining and north of Parlor.

The pool table is scenery in Den. The description of the pool table is "[if the statue is onfire]The pool table is kicking and contorting itself, trying to get away, but it can't support its own weight[otherwise]Your gorge rises when you look at this pool table, and this is why:[paragraph break]John almost never brings the same woman home twice. One exception is Judy, who shows up every couple of months. Every time John has her over, Judy wants to shoot pool. Every time she plays, she manages to spill her drink on the table or rip the felt or [italic type]something,[roman type] and it is your job, every time, to get the table refelted.[paragraph break]You hate Judy[end if]."

[% "Judy is Your Viet Nam" was a fairly new song when this game was written. I had a fairly unsophisticated understanding of the character in the song at the time, and I don't think I did her justice.]

The credenza is a scenery supporter in Den. Instead of opening the credenza, say "[if the statue is onfire]You open the credenza. The inside of it is teeming with ants. You close the credenza[otherwise]You've been instructed to let the guests help themselves to drinks[unicode 8212]and you're not allowed to drink on the job[end if]." The description of the credenza is "[if the statue is onfire]The credenza shivers uncontrollably[otherwise]John says he stocks this credenza with exclusively lower-end liquors as a 'distraction,' but how exactly that's supposed to work is beyond you. Breaking into the cellar and making off with the really expensive stuff wouldn't be that much harder[end if]."

[% "The inside of it is teeming with ants." is a good example of how I wrote the creepy back-half-of-the-game text. I was rushed, but I knew that the mood I wanted would be best conveyed with a minimum of detail.]

Some bar stools are scenery in Den. Understand "stool" or "bar stool" as the bar stools. The description of the bar stools is "[if the statue is onfire]The bar stool glares at you[otherwise]After standing around all evening, even these uncomfortable stools look inviting[end if]."

Some pool cues are scenery in Den. Understand "pool cue" or "cue" as the pool cues. The description of the pool cues is "[if the statue is onfire]The pool cues have fallen on the floor and are twisting around each other like mating snakes. You should look away[otherwise]According to John, those cues are the best. They're from Germany[end if]."

Some pool balls are scenery in Den. Understand "pool ball" or "cue ball" as the pool balls. The description of the pool balls is "[if the statue is onfire]Nobody's better than anybody else. From now on, they're all 5-balls. Good for them[otherwise]The balls['] irregular clacking annoys you to no end[end if]."

[% You probably missed it, but the description of the pool balls while the house is on fire is MY FAVORITE.]

Instead of going nowhere in den, say "[if the statue is onfire]The way to the entrance is through the parlor, to the south[otherwise]The dining room is west of here; the parlor is south[end if]."

Section 6 - Tunnel

A dia is a kind of thing.

[% Eventually we'll see that the category "dia" is meant for dials.]

Tunnel is a room. "Technically this is more like an antechamber for the main cellar, but the room is longer than it is wide, and the ceiling is pretty low. Besides a boarded-up rathole, there's nothing to look at in here but the stairs up and the (infuriating) door in the south." Tunnel is down from Kitchen.

The boarded-up rathole is scenery in tunnel. Understand "rat" or "hole" or "rat hole" or "board" or "boards" as the rathole. The description of the rathole is "Those pests probably could chew through these boards if they really wanted, but they seem to have gotten the message and found someone else to harass."

Instead of pulling the boarded-up rathole, try opening the noun.

Instead of opening the boarded-up rathole, say "You couldn't pull the board out with your bare hands, assuming you wanted to in the first place."

The cellar door is a door. The cellar door is scenery. The cellar door is south of tunnel and north of Wine Cellar. The description of the cellar door is "This thing is ridiculous.[paragraph break]The corny combination lock on this door is supposed to keep intruders out of the cellar, protecting the most expensive wines and liquors. It cost thousands of dollars to commission and install. It is a stupid, gaudy piece of junk.[paragraph break]There are three dials. You just turn a dial, and it slides over to the next setting. Each dial has three settings. There are only twenty-seven combinations. Any thief could go through all of them in just a few minutes.[paragraph break][description of the left dial][paragraph break][description of the center dial][paragraph break][description of the right dial][paragraph break]A simple padlock would be so much more effective. So much simpler."

Instead of touching the cellar door, say "Cold. Cold like a broken promise."

[It is blowing my mind right now how complicated the code for this combination lock is. It's ridiculous, especially for a place where the joke is supposed to be that it's too simple. The worst part is, I don't know whether I could execute it more elegantly today.

The use of the planets' symbols is an homage to the planetary imagery in the video for "The Statue Got Me High," as well as Apollo 18's association with International Space Year.]

The left dial is scenery in tunnel. The left dial is a dia. Understand "mercury" or "venus" or "earth" as the left dial. The left dial can be merc, venu, or eart. The left dial is merc. The description of the left dial is "The left dial is marked with the astronomical symbols for Mercury, Venus, and Earth. It is currently pointing at [if merc]Mercury[otherwise if venu]Venus[otherwise]Earth[end if]."

Instead of turning the left dial:
  if the left dial is merc:
    say "You turn the left dial until it points at the symbol for Venus.";
    now the left dial is venu;
  otherwise if the left dial is venu:
    say "You turn the left dial until it points at the symbol for Earth.";
    now the left dial is eart;
  otherwise if the left dial is eart:
    say "You turn the left dial until it points at the symbol for Mercury.";
    now the left dial is merc.

The center dial is scenery in tunnel. The center dial is a dia. Understand "mars" or "jupiter" or "saturn" or "middle" or "middle dial" as the center dial. The center dial can be marsh, jupi, or satu. The center dial is marsh. The description of the center dial is "The center dial has the symbols for Mars, Jupiter, and Saturn. It is pointing at [if marsh]Mars[otherwise if jupi]Jupiter[otherwise]Saturn[end if]."

Instead of turning the center dial:
  if the center dial is marsh:
    say "You turn the center dial until it points at the symbol for Jupiter.";
    now the center dial is jupi;
  otherwise if the center dial is jupi:
    say "You turn the center dial until it points at the symbol for Saturn.";
    now the center dial is satu;
  otherwise if the center dial is satu:
    say "You turn the center dial until it points at the symbol for Mars.";
    now the center dial is marsh.

The right dial is scenery in tunnel. The right dial is a dia. Understand "uranus" or "neptune" or "pluto" as the right dial. The right dial can be uran, nept, or plut. The right dial is uran. The description of the right dial is "The right dial has settings for Uranus, Neptune, and Pluto. The symbol for Pluto is the stupidest; it's just a combination of the letters P and L. The dial is currently set to [if uran]Uranus[otherwise if nept]Neptune[otherwise]Pluto[end if]." The right dial is either dan or nap. The right dial is dan.

Instead of turning the right dial:
  if the right dial is uran:
    say "You turn the right dial until it points at the symbol for Neptune.";
    if the right dial is dan:
      if the statue is in dining:
        say "[line break]You hear a scream upstairs. Someone must have just been introduced to Peter.";
        now the right dial is nap;
    now the right dial is nept;
  otherwise if the right dial is nept:
    say "You turn the right dial until it points at the idiotic symbol for Pluto.";
    now the right dial is plut;
  otherwise if the right dial is plut:
    say "You turn the right dial until it points at the symbol for Uranus.";
    now the right dial is uran.

Understand "set [something]" as turning.

Planet is a kind of value. The planets are mercury, venus, earth, mars, jupiter, saturn, uranus, neptune, pluto.

Sturning is an action applying to one thing and one planet. Understand "set [something] to [a planet]" and "turn [something] to [a planet]" as sturning.

[% Inform 7 has a default "setting it to" action, but I decided to supplement it with "sturning" for whatever reason. It is very possible that it had to do with me not really knowing how "setting it to" worked at the time.

Instead of sturning: try turning the noun.

Check opening the cellar door:
  If the left dial is venu:
    if the center dial is jupi:
      if the right dial is nept:
        now the cellar door is open;
        say "The door swings open." instead;
      otherwise:
        say "The door does not budge. You must not have the right combination." instead;
    otherwise:
      say "The door does not budge. You must not have the right combination." instead;
  otherwise:
    say "The door does not budge. You must not have the right combination." instead.

Check going up in Tunnel:
  if progression is 7:
    if the player carries a boite:
      continue the action;
    otherwise:
      say "John expects you to return carrying a bottle of wine."

Section 7 - Cellar

Wine Cellar is a room. "John only buys the most expensive wines and spirits he can find. In the eyes of his friends, anyway, that makes him a conoisseur. This room isn't packed to the brim, but what it does contain is worth defending."

[% Ugh there's a typo!]

A bottle of Thunderbird is here. Understand "sickly yellow" or "sickly" or "yellow" as the bottle of Thunderbird. The initial appearance of the bottle of Thunderbird is "A sickly red and yellow bottle lying on its side in the corner would seem to be the exception." The description of the bottle of Thunderbird is "[if handled]You regard the bottle with disgust. You couldn't possibly serve it to the guests. Maybe you could use it to kill a houseplant[otherwise]What is this swill doing here? How did it get past the security system? It probably belongs to Chucky[end if]."

[% Thunderbird is a real terrible wine that inspired a real great TMBG song. It serves no purpose in this game but to let you choose to disappoint John in the end.]

A boite is a kind of thing. The bottle of thunderbird is a boite. The bottle of prevenge is a boite.

[% Naming the kind "bottle" was not an option in this case. (The parser is REALLY WEIRD about plurals of kinds—I won't get into it.) But I know a little French, and here that comes in handy: "boîte" means "small box." I thought it meant "bottle."]

Check taking the bottle of Thunderbird:
  If the player carries the bottle of Prevenge:
    silently try dropping the bottle of Prevenge;
    now the player carries the bottle of Thunderbird;
    say "You cannot gracefully carry two wine bottles at once. You drop the other bottle first, then scoop up the disgusting one." instead;
  Otherwise if the player carries the crowbar:
    silently try dropping the crowbar;
    now the player carries the bottle of Thunderbird;
    say "You drop the crowbar so that you can carry the repellent bottle." instead.

Instead of opening the bottle of Thunderbird, say "You don't have a corkscrew handy, which is just as well. Just the fumes off of this stuff could be hazardous to your health."

[% The above pieces of text exemplify an odd duality in the narrator's voice. "The repellent bottle" is the voice of the player character, an extremely stuffy individual who uses words like "repellent" to demonstrate refinement. "The fumes off of this stuff" is the voice of the author, a much less formal guy who I think is making fun of the player character sometimes for being so serious. This all makes sense to me, obviously, but I bet it reads as plain old "inconsistent tone" to some players.]

Instead of drinking a boite: try opening the noun.

Instead of opening the bottle of Prevenge, say "You don't have a corkscrew handy, but John probably knows where one is."

The crate of Prevenge is a closed openable container in wine cellar. Understand "lid" or "nail" or "nails" or "box" as the crate of prevenge. The printed name of the crate of Prevenge is "crate of Prévenge". The initial appearance of the crate of prevenge is "Nearby is a crate of a particular wine which John apparently thinks is worth saving for a special occasion."

[% "Prevenge" is not an especially great song, says me, but it has a title that can be made to look like the name of a region of France, which works great for our present purposes.]

Instead of examining the crate of Prevenge, say "[if closed]The sides read 'PRÉVENGE,' which name does not inspire as much awe in your as it does in John and his friends.[paragraph break][italic type]Qua[roman type] wine, it's nothing special; most of its appeal is in how difficult it is to obtain. The bottlers have seen fit to add to this element of the experience by bolting down the lid of the crate[otherwise]The crate is open, ready for all the special occasions John will enjoy in the future[end if]."

Numc is a number that varies. Numc is 0.

Check opening the crate of Prevenge:
  if numc is 0:
    say "You give the top of the crate a tug; it is nailed down. You can't open this crate with your bare hands and leave with your fingernails intact." instead;
  otherwise if numc is 4:
    say "It's already open." instead;
  otherwise:
    say "Although not all the nails are still stuck in the lid, you'd still prefer not to risk broken nails or splinters by yanking out the rest with your bare hands." instead.

Understand the command "open" as something new. Opening with is an action applying to two things. Understand "open [something] with [something]" and "pry [something] open with [something]" and "pry [something] with [something]" as opening with. Understand "use [something] with [something]" as opening with (with nouns reversed). Understand "use [something] on [something]" as opening with (with nouns reversed).

Understand "open [something]" and "pry [something]" and "pry [something] open" as opening.

Check inserting something into the crate of prevenge:
  if the noun is the bottle of prevenge:
    continue the action;
  otherwise if the noun is the bottle of thunderbird:
    say "A hilarious practical joke! A hilarious practical joke indeed. You can't wait until it pays off, which will probably be a year from now.";
    continue the action;
  otherwise:
    say "There wouldn't be much point in that."

Instead of taking the crate of prevenge: say "Taking the entire crate upstairs would be too much[unicode 8212]no matter [italic type]who[roman type] is visiting."

The crate of Prevenge contains a bottle of Prevenge. The printed name of the bottle of Prevenge is "bottle of Prévenge". The description of the bottle of Prevenge is "You had the pleasure of experiencing Prévenge at the same tasting where John decided he had to buy several crates. It's nothing special."

Check taking the bottle of Prevenge:
  if the player carries the bottle of Thunderbird:
    silently try dropping the bottle of Thunderbird;
    now the player carries the bottle of Prevenge;
    say "You cannot gracefully carry two wine bottles at once. You drop the other bottle in favor of the Prévenge." instead;
  otherwise if the player carries the crowbar:
    silently try dropping the crowbar;
    now the player carries the bottle of Prevenge;
    say "You drop the crowbar so that you can carry the Prévenge." instead.

A crowbar is here. The initial appearance of the crowbar is "A crowbar leans against the wall." The description of the crowbar is "Crowbars seem such mean tools, and yet there is an elegance to them."

Check taking the crowbar:
  if the player carries the bottle of thunderbird:
    silently try dropping the bottle of thunderbird;
    now the player carries the crowbar;
    say "You happily discard your bottle, so as to carry the crowbar with both hands." instead;
  otherwise if the player carries the bottle of Prevenge:
    silently try dropping the bottle of prevenge;
    now the player carries the crowbar;
    say "You carefully set down the Prévenge, so that you can carry the crowbar with both hands." instead.

After taking the crowbar, say "It's a crowbar, but you take it.[paragraph break]"

[% THIS IS HILARIOUS. In Curses!, whenever you pick up the wrench, the response is "It's a wrench, but you take it." When I first played the game I had no idea that "it's a wrench" was any type of idiomatic phrase, but I understood that some sort of joke was going on. My message about taking the crowbar is a loving homage to that immortal sentence, which made as much sense to me as this one here makes to anybody else in the world.]

Section 8 - Lawn

[% The "lawn" room is declared indirectly by the definition of the front door in the foyer, and since the only thing that happens here is the end-of-game rule, there's no need to say anything about it. Apparently there's a need for an empty section devoted to it however.]

Chapter 2 - People Other Than Chucky

Progression is a number that varies. Progression is 0.

[% Progression is the number of guests whom the PC has interrogated about their seating preferences.]

Check putting the stack of place cards on something:
  if the second noun is the huge table:
    if progression is 0:
      say "You aren't sure yet about where each card should go. If your haphazard seating arrangement were to upset one of the guests, the entire evening might be ruined." instead;
    otherwise if progression is 6:
      say "You pull out one card from the stack to place on the table, but stop. Something doesn't seem right." instead;
    otherwise:
      say "Although a picture of the ideal seating arrangement is forming in your mind, you can't yet bring yourself to put your cards on the table. There must be some guest whom you haven't asked yet about their preferences.";
  otherwise:
    say "The guests cannot be expected to sit around [the second noun]." instead.

Instead of dropping the stack of place cards:
  say "You don't exactly relish carrying the cards around, but you cannot bring yourself to abandon your seat-arranging duties."

[% There's no code for the solution to the place card problem, so I guess we'll talk about it here: It is unsolvable. The guests' demands contradict each other! However, if you added a seat for an additional male guest, it would be possible to make everybody happy.

Both "puzzles" in the game screw with the player in different ways, and I feel like in many cases the player was less entertained than the author was. I played a game recently that had numerous joke-puzzles along these lines, and it ticked me off: The designer seemed to hold the concept of puzzles in contempt, and included them in the game just for the sake of pointing out how stupid it is to include puzzles in games.

Good puzzles are rad, because they're fun. They give you a chance to be clever. The place card puzzle only lets you feel clever if you figure out that it's intentionally unsolvable, which is a heck of a guess to make—most reasonable players are going to assume that they're missing something, or that I made a mistake. The combination lock puzzle lets you feel clever if you put in the work to brute force it, but everyone knows brute forcing a puzzle is cheating. So I don't know.

Both puzzles have qualities to recommend them, and neither was designed out of any ill intention, of disdain for the player or for the concept of puzzles. If you dislike either of them, though, I think I get where you're coming from.]

Talking to is an action applying to one thing. Understand "talk to [something]" as talking to.

[% The mode of conversation with NPCs is always an interesting choice in a text adventure. Inform 7's built-in machinery assumes that you'll ASK or TELL a given character ABOUT a certain topic, which is a lot of fun (you can reward players' creativity and curiosity by including including responses for a lot of different topics) but it can also be a lot of work to include even the minimum reasonable amount of topics.

I have a lot to say about choice-based conversation models but this isn't really the place.

What I did for this game was reduce (almost) all NPC conversation to a single "talking to" action, which is probably the right move for a short game that's focused more on the NPCs' personalities than on the PC's. John, the main NPC, gets some specific responses to ">ASK JOHN ABOUT..." This kind of makes sense, but I don't think I'd include that kind of asymmetry in a game I wrote today.]

Instead of showing something to someone: Try talking to the second noun.

Instead of asking someone about something: Try talking to the noun.

Instead of telling someone about something: Try talking to the noun.

Instead of giving something to someone: Try talking to the second noun.

[% This game was nominated for a Best NPCs XYZZY. You are about to see how little there is, internally, to each of these characters. That jerk Chucky was the most complicated one.]

Section 1 - Garry Horrible

[% Garry is Mister Horrible from "Someone Keeps Moving My Chair." He has little to do with the song (in this game) and instead offers a weird perspective on this game's theme of guilt.]

Garry Horrible is a man in Dining. Understand "Mr Horrible" or "Mister Horrible" as Garry Horrible. The printed name of Garry Horrible is "Garry". The initial appearance of Garry Horrible is "[one of]Somebody jumps as you walk in. It's John's friend Garry, apparently startled by your entrance[or]Garry leans forward with both hands on the table, staring into the grain of the wood[stopping]." The description of Garry Horrible is "Although lacking your boss's level of animal magnetism, Garry Horrible has charm and wit enough to make up for his unfortunate name. Most of the time.[paragraph break]Tonight, he looks like a nervous wreck. There are dark circles under his eyes; his breathing is too loud. His is not a demeanour appropriate to a dinner party."

Instead of talking to Garry Horrible the first time:
  say "You open your mouth to speak to Garry at just the moment that he apparently gathers the courage to talk to you.[paragraph break]'Do you see that painting up there?' he rasps, indicating the portrait on the north wall. 'Don't you think there's something messed up with that guy? He looks really judgmental, right? Like he's judging me. Or you.'[paragraph break]You take a moment to formulate a diplomatic answer, but other thoughts distract you. Why, Garry, are you standing in here, away from the rest of the party, if you hate that painting so much? What is going on in your life that makes you worried that a [italic type]painting[roman type] is judging you?[paragraph break]Garry goes on without you. 'I don't like him. I feel like he's looking at me. You know what? When we sit down for dinner, try and make sure I'm sitting somewhere where I don't have to look at him. One of these two seats,' he says. He points with a shaking hand at the two chairs on the north side of the table.[paragraph break]You nod.";
  increase progression by 1.

Instead of talking to Garry Horrible:
  say "[if the statue is onfire]'I did something bad,' he mumurs, without opening his eyes. 'I took something that didn't belong to me.'[paragraph break]He grimaces. 'I stole from my office. I stole a chair.'[paragraph break]You roll your eyes.[paragraph break]'But I don't deserve a chair. Even the electric chair is too good for me. The statue has come to punish me, and I'll wait here for him to do what he will. After he gets done with John.' He takes a deep breath.[paragraph break]'Message repeats. I did something bad. I took something that didn't belong to me.' Oh, for Pete's sake[otherwise]'Remember!' Garry mutters, almost whispering. 'One of these seats facing away from the painting!' Yeah, yeah[end if]."

Section 2 - Captain Miles

[% Captain Miles is "The Cap'm," and he's based partially on a friend of a friend who had a boat.

"Seems to be nursing one of his migraines" reads to me like I was quoting something, but I can't place it.]

Captain Miles is a man in Den. Understand "Cap" or "Capm" or "Capm Miles" or "Cap'm" or "The Cap'm" as Captain Miles. The initial appearance of Captain Miles is "[if the statue is onfire]Captain Miles seems to be nursing one of his migraines[otherwise]Captain Miles is here, lining up a shot at the pool table[end if]." The description of Captain Miles is "It isn't clear to you whether Captain Miles's title was earned in the armed forces, or signifies his command over some sailing vessel, or else is a nickname bestowed by your boss. Looking him over, the second option seems likely, based on his piped blazer and its nautical-looking coat of arms.[paragraph break]John has referred to Miles and Miss Idie as 'a lock,' although apparently no formal proposal has been made. Currently he appears primarily focused on his game of pool."

Captain Miles wears a piped blazer. The coat of arms is part of the piped blazer.

[% But neither gets a description! I guess I may have made a conscious decision not to include additional description of the NPCs' clothes and accessories, but I think it's more likely that I was in a hurry and I forgot.

In a perfect game, >EXAMINE BLAZER would yield an interesting or at least sensical response that either adds some detail to the world of the game ("The Captain's blazer reminds you of when you were a bellhop at Hell Hotel, etc. etc.") or calls off the player's interest so we can move on to something else ("It's a very smart-looking blazer.") As implemented here, the response is "You see nothing special about the piped blazer."—which, to anyone who knows anything about text adventures, reads as "HELLO PLAYER, I DIDN'T WRITE  A DESCRIPTION" in large, Pokey the Penguin-esque letters.

But if you really don't want the player to worry about the blazer, you can "zero-implement" the object by writing 'understand "blazer" as Captain Miles,' which redirects >EXAMINE BLAZER to print the description of Miles and making it impossible to really focus on the blazer itself. This isn't especially subtle but it gets the message across.]

Instead of talking to Captain Miles the first time:
  say "'Oh, there you are,' says Miles as you approach. 'Listen, I don't know if you've decided who's sitting where for dinner. But I've been getting these real bad migraines lately.'[paragraph break]Ivan looks up from the pool table. 'No kidding? I can give you something for that.' He pulls a pad of paper from inside his jacket.[paragraph break]Miles turns away from you and back toward Ivan. 'Well, I don't know for sure if they're migraines. I know that I'm really sensitive to light.'[paragraph break]Ivan is already writing. 'Doesn't matter. How about codeine? You seem to me like a codeine kind of guy.' He looks slantways at Miles for a moment, then goes back to scribbling. 'Yeah. Here you go. You can get this filled wherever.'[paragraph break]He rips off the sheet and pushes it into Miles's hand. 'Thanks,' Miles stutters, before he turns back to you.[paragraph break]'In the meantime I guess, I'm just saying, I'd rather not sit in that chair that's facing the window while the sun's going down.'";
  increase progression by 1.

Instead of talking to Captain Miles:
  say "Miles diverts his attention from the pool table for a moment. 'Yeah, no, I'm not picky. I'd just rather not sit where I'd have to stare into the sun."

[% Below is the first mention of the room called "barracks," which I used to add to every game where I stored entities that I needed to be outside of the game map entirely. This was before I learned how to use the built-in Inform 7 concept of an object being "offstage" and sending things there by "removing them from play." This is what I'm talking about when I say some of this code is embarrassing.]

Before talking to Captain Miles:
  if the statue is onfire:
    now miles is in barracks;
    say "Miles looks at you through his fingers, still rubbing his head. 'Oh, there you are,' he says.[paragraph break]His fingers are skeleton bones instead of fingers. 'I'm supposed to say something, so I'll say it to you. The thing I'm supposed to say is, I'm sorry.'[paragraph break]Now the skin and muscle is gone from his face. 'Not sure what I'm supposed to be sorry about. It's really hot in here, and it's hard to think. Maybe I'm supposed to be sorry about Hope, you know.'[paragraph break]His face comes back for a second so he can squint in frustration. 'That's a complicated thing to be sorry for. But the other stuff I did, I don't want to admit to doing. So I'll go with that.'[paragraph break]He nods his skull a couple times, then his skeleton falls apart and burns up." instead.

Before examining captain miles:
  if the statue is onfire:
    now miles is in barracks;
    say "Miles looks at you through his fingers, still rubbing his head. 'Oh, there you are,' he says.[paragraph break]His fingers are skeleton bones instead of fingers. 'I'm supposed to say something, so I'll say it to you. The thing I'm supposed to say is, I'm sorry.'[paragraph break]Now the skin and muscle is gone from his face. 'Not sure what I'm supposed to be sorry about. It's really hot in here, and it's hard to think. Maybe I'm supposed to be sorry about Hope, you know.'[paragraph break]His face comes back for a second so he can squint in frustration. 'That's a complicated thing to be sorry for. But the other stuff I did, I don't want to admit to doing. So I'll go with that.'[paragraph break]He nods his skull a couple times, then his skeleton falls apart and burns up." instead.

Section 3 - Doctor Ivan Worm

[% Doctor Worm is "Doctor Worm," of course. He also resembles a weird inverse Gregory House, writing frivolous descriptions for painkillers. His attire is House's but also mine.]

Doctor Ivan Worm is a man in Den. The printed name of Doctor Ivan Worm is "Ivan". Understand "Doctor Worm" or "Dr Worm" as Ivan Worm. The initial appearance of Doctor Ivan Worm i

Latest Jobs

Sucker Punch Productions

Bellevue, Washington
08.27.21
Combat Designer

Xbox Graphics

Redmond, Washington
08.27.21
Senior Software Engineer: GPU Compilers

Insomniac Games

Burbank, California
08.27.21
Systems Designer

Deep Silver Volition

Champaign, Illinois
08.27.21
Senior Environment Artist
More Jobs   

CONNECT WITH US

Register for a
Subscribe to
Follow us

Game Developer Account

Game Developer Newsletter

@gamedevdotcom

Register for a

Game Developer Account

Gain full access to resources (events, white paper, webinars, reports, etc)
Single sign-on to all Informa products

Register
Subscribe to

Game Developer Newsletter

Get daily Game Developer top stories every morning straight into your inbox

Subscribe
Follow us

@gamedevdotcom

Follow us @gamedevdotcom to stay up-to-date with the latest news & insider information about events & more